Binary WebSocket Protocol

[timestamp:i64][value:f64][series_len:u16][tag_count:u16][series_utf8][tag_len:u16+tag_utf8]...

[tag_len:u16][tag_utf8]

fn decodeBinaryMessage(allocator: std.mem.Allocator, data: []const u8, tag_scratch: *std.ArrayList([]const u8)) !DecodedMessage {
    // little-endian:
    // [timestamp:i64][value:f64][series_len:u16][tag_count:u16][series][tag_len:u16+tag_bytes]...
    const header_len = 8 + 8 + 2 + 2;
    if (data.len < header_len) return error.InvalidMessage;

    var offset: usize = 0;
    const timestamp_bits = std.mem.readInt(u64, data[offset..][0..8], .little);
    const timestamp: i64 = @bitCast(timestamp_bits);
    offset += 8;

    const value_bits = std.mem.readInt(u64, data[offset..][0..8], .little);
    const value: f64 = @bitCast(value_bits);
    offset += 8;

    const series_len = @as(usize, std.mem.readInt(u16, data[offset..][0..2], .little));
    offset += 2;
    const tag_count = @as(usize, std.mem.readInt(u16, data[offset..][0..2], .little));
    offset += 2;

    if (offset + series_len > data.len) return error.InvalidMessage;
    const series = data[offset .. offset + series_len];
    offset += series_len;

    tag_scratch.clearRetainingCapacity();
    try tag_scratch.ensureTotalCapacity(allocator, tag_count);

    var i: usize = 0;
    while (i < tag_count) : (i += 1) {
        if (offset + 2 > data.len) return error.InvalidMessage;
        const tag_len = @as(usize, std.mem.readInt(u16, data[offset..][0..2], .little));
        offset += 2;
        if (offset + tag_len > data.len) return error.InvalidMessage;
        try tag_scratch.append(allocator, data[offset .. offset + tag_len]);
        offset += tag_len;
    }

    if (offset != data.len) return error.InvalidMessage;

    return .{
        .timestamp = timestamp,
        .value = value,
        .series = series,
        .tags = tag_scratch.items,
    };
}